source: orbit/arduino/puzzlebox_orbit_A_HMRMFM/puzzlebox_orbit_A_HMRMFM.ino @ 7e55322

/*

 Mimics the fade example but with an extra parameter for frequency. It should dim but with a flicker 
 because the frequency has been set low enough for the human eye to detect. This flicker is easiest to see when 
 the LED is moving with respect to the eye and when it is between about 20% - 60% brighness. The library 
 allows for a frequency range from 1Hz - 2MHz on 16 bit timers and 31Hz - 2 MHz on 8 bit timers. When 
 SetPinFrequency()/SetPinFrequencySafe() is called, a bool is returned which can be tested to verify the 
 frequency was actually changed.
 
 This example runs on mega and uno.
 */

#include <PWM.h>

char outerCode[]={66,66,80,51,36,51,80,66,66,66,80,51,36,51,80,66,66,80,51,36,51,80,66,66,66,80,51,36,51,36,36,51,36,51,36,36,51,36,51,36,51,80,66,66,66,80,51,36,51,80};

//use pin 11 on the Mega instead, otherwise there is a frequency cap at 31 Hz
int IR = 10;                // the pin that the Infrared LED is attached to
int ON = 128;         // 17.5us/26us = 172.3/256
int OFF = 0;
int32_t frequency = 38400; //frequency (in Hz)

//variables start with "_" means global variable 
char _height=88;
char _pitch=63;
char _rotation=78;
char _channel='A';
char _command;

//generate ON/OFF control signals, with starting and stopping PWM generator
void innerCycle(int onTime, int offTime)
{
  pwmWrite(IR, ON);
  delayMicroseconds(onTime);
  pwmWrite(IR, OFF);
  delayMicroseconds(offTime);
}

void emitCode(char BIT)
{
  if (BIT) innerCycle(671,732);// 1
  else innerCycle(337,402);// 0
}

void sendCode(char height,char rotation,char pitch)
{
  char n;
  
  //starting code, with special time period.
  innerCycle(730,392); //(773 414)->824 450
  innerCycle(730,392); 
  //height
  for (n=6; n>=0; n--)  emitCode((height >> n) & 1);//emitCode generate LOWs between HIGHs as same as the parameter.
  
  emitCode(1);// meaning unclear
  
  //channel selection first half
  if (_channel=='C') emitCode(1);
  else emitCode(0);  //this digit equals 0 in channel A or B
  
  for (n=6; n>=0; n--)  emitCode((rotation >> n) & 1);//rotation
  
  //channel selection second half
  if (_channel=='A') emitCode(1);
  else emitCode(0); //if channel B or C, this digit equals 0;
  
  emitCode(0);//meaning unclear
  
  for (n=6; n>=0; n--)  emitCode((pitch >> n) & 1);//pitch  
    
  // unclear, "random" code  
  emitCode(0); emitCode(1); emitCode(0);
  
  //finish code
  emitCode(1);
}

void setup()
{
  pinMode(13, OUTPUT);
  digitalWrite(13,LOW);
  //initialize all timers except for 0, to save time keeping functions
  InitTimersSafe(); 

  //sets the frequency for the specified pin
  bool success = SetPinFrequencySafe(IR, frequency);
  
  //if the pin frequency was set successfully, turn pin 13 on
  if(success) {
    digitalWrite(13, HIGH);    
  }
  Serial.begin(9600);
}

void loop()
{int i;
 // 668533535335358
 for (i=1;i<sizeof(outerCode);i++)
 {
  
  if (Serial.available() > 0) 
  {
    _command = Serial.read();
    switch (_command)
    {
      case 'U':  _height+=5;  break;
      case 'D':  _height-=5;  break;
      case 'L':  _rotation+=5;  break;
      case 'R':  _rotation-=5;  break;
      case 'F':  _pitch+=5;  break;
      case 'B':  _pitch-=5;  break;
      case '1':  _channel='A';  break;
      case '2':  _channel='B';  break;
      case '3':  _channel='C';  break;
    }
  }
  
  sendCode(_height,_rotation,_pitch);
  delay(outerCode[i]);
 }

}